.macro SOFTMAX_MAX_PANEL
	mov $a7, $a6
	ld64step $a0:1, $mzero, $m3+=, 1
	.rept 3
	{ ld64step $a0:1, $mzero, $m3+=, 1
	  f16v4max $a6:7, $a6:7, $a0:1 }
	.endr
	f16v4max $a6:7, $a6:7, $a0:1
	f16v2max $a6, $a6, $a7
	.endm
	.macro SOFTMAX_EXP_PANEL
	// Prime with zero accumulators so the discarded readout is finite.
	// MIX then returns each preceding quad while starting the next one.
	setzi $a0, 1 << CSR_W_FP_CLR__ZAACC__SHIFT
	uput $FP_CLR, $a0
	ld64step $a0:1, $mzero, $m3+=, 1
	f16v4mix $a2:3, $a0:1, $a4:5
	.rept 3
	ld64step $a0:1, $mzero, $m3+=, 1
	f16v4mix $a2:3, $a0:1, $a4:5
	SOFTMAX_STORE_QUAD
	.endr
	f16v4gacc $a2:3
	SOFTMAX_STORE_QUAD
	.endm
#include "arch/gc_tile_defines.h"

// AMP-left panel order; FP16 probabilities with FP32 maxima and sums.
// m2 weights, m3 scores, m4 query rows, m5 valid keys.
#if ATTENTION_FULL_BLOCK
#define SOFTMAX_FRAME_BYTES 12
#else
#define SOFTMAX_FRAME_BYTES 16
#endif
	.section .text.ATTENTION_SOFTMAX_SYMBOL,"ax",@progbits
	.globl ATTENTION_SOFTMAX_SYMBOL
	.p2align 2
	.type ATTENTION_SOFTMAX_SYMBOL,@function
ATTENTION_SOFTMAX_SYMBOL:
	.supervisor
	// Three segments improve worker rounding for residues 1..4 modulo 6.
	setzi $m0, 128
	cmpult $m0, $m5, $m0
	brnz $m0, .Lsoftmax_whole
	mov $m0, $m4
	setzi $m1, 6
.Lsoftmax_residue:
	cmpult $m6, $m0, $m1
	brnz $m6, .Lsoftmax_choose
	sub $m0, $m0, 6
	bri .Lsoftmax_residue
.Lsoftmax_choose:
	brz $m0, .Lsoftmax_whole
	setzi $m1, 5
	cmpult $m0, $m0, $m1
	brz $m0, .Lsoftmax_whole
	add $m11, $m11, -16
	st32 $m2, $m11, $m15, 0
	st32 $m3, $m11, $m15, 1
	st32 $m4, $m11, $m15, 2
	st32 $m5, $m11, $m15, 3
	setzi $m0, .Lsoftmax_split_max
	runall $m0, $m11, 0
	sync TEXCH_SYNCZONE_LOCAL
	setzi $m0, .Lsoftmax_split_exp
	runall $m0, $m11, 0
	sync TEXCH_SYNCZONE_LOCAL
	setzi $m0, .Lsoftmax_split_sum
	runall $m0, $m11, 0
	sync TEXCH_SYNCZONE_LOCAL
	add $m11, $m11, 16
	br $m10
.Lsoftmax_whole:
	.supervisor
	add $m11, $m11, -SOFTMAX_FRAME_BYTES
	st32 $m2, $m11, $m15, 0
	st32 $m3, $m11, $m15, 1
	st32 $m4, $m11, $m15, 2
#if !ATTENTION_FULL_BLOCK
	st32 $m5, $m11, $m15, 3
#endif
	setzi $m0, .Lsoftmax_worker
	runall $m0, $m11, 0
	sync TEXCH_SYNCZONE_LOCAL
	add $m11, $m11, SOFTMAX_FRAME_BYTES
	br $m10
	.size ATTENTION_SOFTMAX_SYMBOL, .-ATTENTION_SOFTMAX_SYMBOL

	.worker
	.p2align 3
.Lsoftmax_worker:
	ld32 $m5, $mvertex_base, $m15, 2
#if !ATTENTION_FULL_BLOCK
	ld32 $m10, $mvertex_base, $m15, 3
#endif
	get $m4, $WSR
	and $m4, $m4, CSR_W_WSR__CTXTID_M1__MASK
	cmpult $m0, $m4, $m5
	brz $m0, .Lsoftmax_done
	add $m8, $m5, -1
	shl $m8, $m8, 5
.Lsoftmax_row:
	ld32 $m2, $mvertex_base, $m15, 0
	ld32 $m3, $mvertex_base, $m15, 1
	shl $m0, $m4, 5
	add $m3, $m3, $m0
	add $m2, $m2, $m0
	mov $m9, $m3
	// The maximum of finite FP16 inputs is exactly representable in FP16.
	ldconst $a6, 0xfbfffbff
#if ATTENTION_FULL_BLOCK
	setzi $m7, ATTENTION_KEY_BLOCK_COLUMNS / 16 - 1
#else
	shr $m7, $m10, 4
	brz $m7, .Lsoftmax_max_tail
	sub $m7, $m7, 1
#endif
.Lsoftmax_max_panel:
	SOFTMAX_MAX_PANEL
	add $m3, $m3, $m8
	brnzdec $m7, .Lsoftmax_max_panel
#if !ATTENTION_FULL_BLOCK
.Lsoftmax_max_tail:
	and $m7, $m10, 15
	shr $m7, $m7, 1
	brz $m7, .Lsoftmax_max_scalar
	sub $m7, $m7, 1
.Lsoftmax_max_pair:
	ld32step $a0, $mzero, $m3+=, 1
	f16v2max $a6, $a6, $a0
	brnzdec $m7, .Lsoftmax_max_pair
.Lsoftmax_max_scalar:
#endif
	f16v2tof32 $a6:7, $a6
	f32max $a6, $a6, $a7
#if !ATTENTION_FULL_BLOCK
	and $m0, $m10, 1
	brz $m0, .Lsoftmax_max_ready
	ld32 $a0, $m3, $m15, 0
	f16v2tof32 $a0:1, $a0
	f32max $a6, $a6, $a0
.Lsoftmax_max_ready:
#endif
	ldconst $a4, ATTENTION_SCALE_BITS
	f32mul $a7, $a6, $a4
	// Persistent maxima/denominators follow the packed weight matrix.
	ld32 $m6, $mvertex_base, $m15, 0
	setzi $m0, ATTENTION_KEY_BLOCK_COLUMNS * 2
	mul $m0, $m5, $m0
	add $m6, $m6, $m0
	shl $m0, $m4, 2
	add $m6, $m6, $m0
	st32 $a7, $m6, $m15, 0
	f32sub $a5, $azero, $a7
	f32tof16 $a2, $a6
	setzi $a6, 0
	setzi $a7, 0
	mov $m3, $m9
#if ATTENTION_FULL_BLOCK
	setzi $m7, ATTENTION_KEY_BLOCK_COLUMNS / 16 - 1
#else
	shr $m7, $m10, 4
	brz $m7, .Lsoftmax_exp_tail
	sub $m7, $m7, 1
#endif
	.macro SOFTMAX_EXP_PAIR
	f16v2tof32 $a0:1, $a0
	f32v2mul $a0:1, $a4:B, $a0:1
	f32v2add $a0:1, $a5:B, $a0:1
	f32v2tof16 $a0, $a0:1
	f16v2exp $a0, $a0
	{ st32step $a0, $mzero, $m2+=, 1
	  f16v2tof32 $a2:3, $a0 }
	.endm
	// TAS holds +/- the half scale. MIX forms the difference in FP32,
	// avoiding an overflowing intermediate FP16 subtraction.
	mov $a0, $a4
	f32sub $a1, $azero, $a4
	f32v2tof16 $a0, $a0:1
	uput $TAS, $a0
	mov $a4, $a2
	mov $a5, $a2
	.macro SOFTMAX_STORE_QUAD
	f16v2exp $a2, $a2
	f16v2exp $a3, $a3
	{ st32step $a2, $mzero, $m2+=, 1
	  f16v2tof32 $a0:1, $a2 }
	f32v2add $a6:7, $a6:7, $a0:1
	{ st32step $a3, $mzero, $m2+=, 1
	  f16v2tof32 $a0:1, $a3 }
	f32v2add $a6:7, $a6:7, $a0:1
	.endm
.Lsoftmax_exp_panel:
	SOFTMAX_EXP_PANEL
	add $m3, $m3, $m8
	add $m2, $m2, $m8
	brnzdec $m7, .Lsoftmax_exp_panel
#if !ATTENTION_FULL_BLOCK
.Lsoftmax_exp_tail:
	ldconst $a4, ATTENTION_SCALE_BITS
	ld32 $a5, $m6, $m15, 0
	f32sub $a5, $azero, $a5
	and $m7, $m10, 15
	shr $m7, $m7, 1
	brz $m7, .Lsoftmax_exp_odd
	sub $m7, $m7, 1
.Lsoftmax_exp_pair:
	ld32step $a0, $mzero, $m3+=, 1
	SOFTMAX_EXP_PAIR
	f32v2add $a6:7, $a6:7, $a2:3
	brnzdec $m7, .Lsoftmax_exp_pair
.Lsoftmax_exp_odd:
	and $m0, $m10, 1
	brz $m0, .Lsoftmax_zero_tail
	ld32 $a0, $m3, $m15, 0
	f16v2tof32 $a0:1, $a0
	f32v2mul $a0:1, $a4:B, $a0:1
	f32v2add $a0:1, $a5:B, $a0:1
	// Mask the unused lane before exponentiation; it contributes exactly zero.
	ldconst $a1, 0xc77fe000
	f32v2tof16 $a0, $a0:1
	f16v2exp $a0, $a0
	{ st32step $a0, $mzero, $m2+=, 1
	  f16v2tof32 $a2:3, $a0 }
	f32v2add $a6:7, $a6:7, $a2:3
.Lsoftmax_zero_tail:
	and $m7, $m10, 15
	add $m7, $m7, 1
	shr $m7, $m7, 1
	setzi $m0, 8
	sub $m7, $m0, $m7
	brz $m7, .Lsoftmax_zero_panels_setup
	sub $m7, $m7, 1
.Lsoftmax_zero_pair:
	st32step $mzero, $mzero, $m2+=, 1
	brnzdec $m7, .Lsoftmax_zero_pair
.Lsoftmax_zero_panels_setup:
	add $m2, $m2, $m8
	shr $m0, $m10, 4
	setzi $m7, ATTENTION_KEY_BLOCK_COLUMNS / 16 - 1
	sub $m7, $m7, $m0
	brz $m7, .Lsoftmax_sum_ready
	sub $m7, $m7, 1
.Lsoftmax_zero_panel:
	.rept 8
	st32step $mzero, $mzero, $m2+=, 1
	.endr
	add $m2, $m2, $m8
	brnzdec $m7, .Lsoftmax_zero_panel
.Lsoftmax_sum_ready:
#endif
	f32add $a6, $a6, $a7
	shl $m0, $m5, 2
	add $m6, $m6, $m0
	st32 $a6, $m6, $m15, 0
	add $m4, $m4, 6
	cmpult $m0, $m4, $m5
	brnz $m0, .Lsoftmax_row
.Lsoftmax_done:
	exitz $m15

	.macro SOFTMAX_SPLIT_INIT
	ld32 $m5, $mvertex_base, $m15, 2
	get $m9, $WSR
	and $m9, $m9, CSR_W_WSR__CTXTID_M1__MASK
	setzi $m0, 3
	cmpult $m4, $m9, $m0
	brnz $m4, .Lsoftmax_even_\@
	sub $m9, $m9, 3
	setzi $m4, 1
	bri .Lsoftmax_parity_\@
.Lsoftmax_even_\@:
	setzi $m4, 0
.Lsoftmax_parity_\@:
	add $m8, $m5, -1
	shl $m8, $m8, 5
	setzi $m0, ((ATTENTION_KEY_BLOCK_COLUMNS + 47) / 48) * 16
	mul $m1, $m9, $m0
	setzi $m11, ATTENTION_KEY_BLOCK_COLUMNS
	sub $m11, $m11, $m1
	cmpult $m1, $m0, $m11
	brz $m1, .Lsoftmax_capacity_\@
	mov $m11, $m0
.Lsoftmax_capacity_\@:
	.endm

	.macro SOFTMAX_SPLIT_ROW
	ld32 $m2, $mvertex_base, $m15, 0
	ld32 $m3, $mvertex_base, $m15, 1
	// Three FP32 maxima and three sums use the existing extra 16 halves/row.
	setzi $m0, ATTENTION_KEY_BLOCK_COLUMNS * 2 + 8
	mul $m6, $m5, $m0
	add $m6, $m6, $m2
	setzi $m0, 3
	mul $m0, $m4, $m0
	add $m0, $m0, $m9
	shl $m0, $m0, 2
	add $m6, $m6, $m0
	setzi $m0, ((ATTENTION_KEY_BLOCK_COLUMNS + 47) / 48) * 16
	mul $m0, $m9, $m0
	ld32 $m10, $mvertex_base, $m15, 3
	sub $m10, $m10, $m0
	cmpslt $m1, $m10, $mzero
	brz $m1, .Lsoftmax_nonempty_\@
	setzi $m10, 0
.Lsoftmax_nonempty_\@:
	cmpult $m1, $m11, $m10
	brz $m1, .Lsoftmax_clamped_\@
	mov $m10, $m11
.Lsoftmax_clamped_\@:
	mul $m0, $m0, $m5
	shl $m0, $m0, 1
	shl $m1, $m4, 5
	add $m0, $m0, $m1
	add $m2, $m2, $m0
	add $m3, $m3, $m0
	.endm

	.worker
	.p2align 3
.Lsoftmax_split_max:
	SOFTMAX_SPLIT_INIT
.Lsoftmax_split_max_row:
	cmpult $m0, $m4, $m5
	brz $m0, .Lsoftmax_done
	SOFTMAX_SPLIT_ROW
	ldconst $a6, 0xfbfffbff
	shr $m7, $m10, 4
	brz $m7, .Lsoftmax_split_max_tail
	sub $m7, $m7, 1
.Lsoftmax_split_max_panel:
	SOFTMAX_MAX_PANEL
	add $m3, $m3, $m8
	brnzdec $m7, .Lsoftmax_split_max_panel
.Lsoftmax_split_max_tail:
	and $m7, $m10, 15
	brz $m7, .Lsoftmax_split_max_reduce
	and $m1, $m7, 1
	shr $m7, $m7, 1
	brz $m7, .Lsoftmax_split_max_odd
	sub $m7, $m7, 1
.Lsoftmax_split_max_pair:
	ld32step $a0, $mzero, $m3+=, 1
	f16v2max $a6, $a6, $a0
	brnzdec $m7, .Lsoftmax_split_max_pair
.Lsoftmax_split_max_odd:
	brz $m1, .Lsoftmax_split_max_reduce
	ld32 $a0, $m3, $m15, 0
	f16v2tof32 $a0:1, $a0
	f32tof16 $a0, $a0
	f16v2max $a6, $a6, $a0
.Lsoftmax_split_max_reduce:
	f16v2tof32 $a6:7, $a6
	f32max $a6, $a6, $a7
	st32 $a6, $m6, $m15, 0
	add $m4, $m4, 2
	bri .Lsoftmax_split_max_row

	.p2align 3
.Lsoftmax_split_exp:
	SOFTMAX_SPLIT_INIT
.Lsoftmax_split_exp_row:
	cmpult $m0, $m4, $m5
	brz $m0, .Lsoftmax_done
	SOFTMAX_SPLIT_ROW
	shl $m0, $m9, 2
	sub $m0, $m6, $m0
	ld32 $a0, $m0, $m15, 0
	ld32 $a1, $m0, $m15, 1
	ld32 $a2, $m0, $m15, 2
	f32max $a0, $a0, $a1
	f32max $a0, $a0, $a2
	f32tof16 $a4, $a0
	mov $a5, $a4
	brnz $m9, .Lsoftmax_split_scale
	ldconst $a1, ATTENTION_SCALE_BITS
	f32mul $a2, $a0, $a1
	ld32 $m0, $mvertex_base, $m15, 0
	setzi $m1, ATTENTION_KEY_BLOCK_COLUMNS * 2
	mul $m1, $m5, $m1
	add $m0, $m0, $m1
	shl $m1, $m4, 2
	add $m0, $m0, $m1
	st32 $a2, $m0, $m15, 0
.Lsoftmax_split_scale:
	ldconst $a0, ATTENTION_SCALE_BITS
	f32sub $a1, $azero, $a0
	f32v2tof16 $a0, $a0:1
	uput $TAS, $a0
	setzi $a6, 0
	setzi $a7, 0
	shr $m7, $m10, 4
	brz $m7, .Lsoftmax_split_exp_tail
	sub $m7, $m7, 1
.Lsoftmax_split_exp_panel:
	SOFTMAX_EXP_PANEL
	add $m3, $m3, $m8
	add $m2, $m2, $m8
	brnzdec $m7, .Lsoftmax_split_exp_panel
.Lsoftmax_split_exp_tail:
	and $m7, $m10, 15
	brz $m7, .Lsoftmax_split_padding
	f16v2tof32 $a2:3, $a4
	ldconst $a4, ATTENTION_SCALE_BITS
	f32mul $a5, $a2, $a4
	f32sub $a5, $azero, $a5
	shr $m7, $m7, 1
	brz $m7, .Lsoftmax_split_exp_odd
	sub $m7, $m7, 1
.Lsoftmax_split_exp_pair:
	ld32step $a0, $mzero, $m3+=, 1
	SOFTMAX_EXP_PAIR
	f32v2add $a6:7, $a6:7, $a2:3
	brnzdec $m7, .Lsoftmax_split_exp_pair
.Lsoftmax_split_exp_odd:
	and $m0, $m10, 1
	brz $m0, .Lsoftmax_split_zero_tail
	ld32 $a0, $m3, $m15, 0
	f16v2tof32 $a0:1, $a0
	f32v2mul $a0:1, $a4:B, $a0:1
	f32v2add $a0:1, $a5:B, $a0:1
	ldconst $a1, 0xc77fe000
	f32v2tof16 $a0, $a0:1
	f16v2exp $a0, $a0
	{ st32step $a0, $mzero, $m2+=, 1
	  f16v2tof32 $a2:3, $a0 }
	f32v2add $a6:7, $a6:7, $a2:3
.Lsoftmax_split_zero_tail:
	and $m7, $m10, 15
	add $m7, $m7, 1
	shr $m7, $m7, 1
	setzi $m0, 8
	sub $m7, $m0, $m7
	brz $m7, .Lsoftmax_split_after_tail
	sub $m7, $m7, 1
.Lsoftmax_split_zero_pair:
	st32step $mzero, $mzero, $m2+=, 1
	brnzdec $m7, .Lsoftmax_split_zero_pair
.Lsoftmax_split_after_tail:
	add $m2, $m2, $m8
.Lsoftmax_split_padding:
	shr $m7, $m11, 4
	add $m0, $m10, 15
	shr $m0, $m0, 4
	sub $m7, $m7, $m0
	brz $m7, .Lsoftmax_split_store_sum
	sub $m7, $m7, 1
.Lsoftmax_split_zero_panel:
	.rept 8
	st32step $mzero, $mzero, $m2+=, 1
	.endr
	add $m2, $m2, $m8
	brnzdec $m7, .Lsoftmax_split_zero_panel
.Lsoftmax_split_store_sum:
	setzi $m0, 12
	mul $m0, $m5, $m0
	add $m6, $m6, $m0
	f32add $a6, $a6, $a7
	st32 $a6, $m6, $m15, 0
	add $m4, $m4, 2
	bri .Lsoftmax_split_exp_row

	.p2align 3
.Lsoftmax_split_sum:
	ld32 $m5, $mvertex_base, $m15, 2
	ld32 $m2, $mvertex_base, $m15, 0
	setzi $m0, ATTENTION_KEY_BLOCK_COLUMNS * 2 + 4
	mul $m0, $m5, $m0
	add $m2, $m2, $m0
	get $m4, $WSR
	and $m4, $m4, CSR_W_WSR__CTXTID_M1__MASK
.Lsoftmax_split_sum_row:
	cmpult $m0, $m4, $m5
	brz $m0, .Lsoftmax_done
	shl $m0, $m4, 2
	add $m3, $m2, $m0
	setzi $m0, 16
	mul $m0, $m5, $m0
	add $m6, $m2, $m0
	setzi $m0, 12
	mul $m0, $m4, $m0
	add $m6, $m6, $m0
	ld32 $a0, $m6, $m15, 0
	ld32 $a1, $m6, $m15, 1
	ld32 $a2, $m6, $m15, 2
	f32add $a0, $a0, $a1
	f32add $a0, $a0, $a2
	st32 $a0, $m3, $m15, 0
	add $m4, $m4, 6
	bri .Lsoftmax_split_sum_row